subdir('ui')

resource_files = files('im.gzr.MunchMate.gresource.xml')
resources = gnome.compile_resources(
  'im.gzr.MunchMate',
  resource_files,
  source_dir: meson.current_build_dir(),
  dependencies: custom_target(
    'blueprints',
    input: blueprints,
    output: '.',
    command: [ find_program('blueprint-compiler'), 'batch-compile', '@OUTPUT@', '@CURRENT_SOURCE_DIR@', '@INPUT@' ],
  ),
  c_name: 'resources',
)

install_subdir('icons/',
  install_dir: join_paths(get_option('datadir'), 'icons/hicolor'))

desktop_file = files('im.gzr.MunchMate.desktop')
install_data(
  desktop_file,
  install_dir: join_paths(get_option('datadir'), 'applications'),
)

metainfo_file = files('im.gzr.MunchMate.metainfo.xml')
install_data(
  metainfo_file,
  install_dir: join_paths(get_option('datadir'), 'metainfo'),
)

# Validating app data
appstreamcli = find_program('appstreamcli', required: false)
if appstreamcli.found()
  test(
    'validate-appdata', appstreamcli,
    args: [ 'validate', '--no-net', '--explain', metainfo_file ],
  )
endif

schema_file = files('im.gzr.MunchMate.gschema.xml')
install_data(
  schema_file,
  install_dir: join_paths(get_option('datadir'), 'glib-2.0', 'schemas')
)

configure_file(
  input: 'im.gzr.MunchMate.service.in',
  output: 'im.gzr.MunchMate.service',
  configuration: configuration_data({
    'bindir': join_paths(get_option('prefix'), get_option('bindir')),
  }),
  install_dir: join_paths(get_option('datadir'), 'dbus-1', 'services')
)